media-sound/jack-tools-9999: LADI version of media-sound/jack-example-tools

media-sound/jack-tools/jack-tools-9999.ebuild

@@ -0,0 +1,63 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson git-r3
+
+DESCRIPTION="Official examples and tools from the JACK project"
+HOMEPAGE="https://jackaudio.org/"
+
+EGIT_REPO_URI="https://github.com/LADI/jack-tools.git"
+EGIT_BRANCH="main"
+
+LICENSE="GPL-2+ zalsa? ( GPL-3+ )"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv x86"
+IUSE="alsa jack-net jack-netsource opus +readline sndfile zalsa"
+
+RDEPEND="
+	virtual/jack
+	alsa? (
+		media-libs/alsa-lib
+		media-libs/libsamplerate
+	)
+	jack-net? (
+		|| (
+			media-sound/jack2[libsamplerate]
+			media-video/pipewire[jack-sdk(-)]
+		)
+	)
+	jack-netsource? (
+		media-libs/libsamplerate
+		opus? ( media-libs/opus[custom-modes] )
+	)
+	readline? ( sys-libs/readline:= )
+	sndfile? ( media-libs/libsndfile )
+	zalsa? (
+		media-libs/alsa-lib
+		media-libs/zita-alsa-pcmi
+		media-libs/zita-resampler:=
+	)
+	!<media-sound/jack-audio-connection-kit-0.126.0
+	!<media-sound/jack2-1.9.21
+	!media-sound/jack-example-tools"
+DEPEND="${RDEPEND}"
+
+DOCS=( CHANGELOG.md README.md )
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature alsa alsa_in_out)
+		$(meson_feature jack{-,_}net)
+		$(meson_feature jack{-,_}netsource)
+		$(meson_feature readline readline_support)
+		$(meson_feature sndfile jack_rec)
+		$(meson_feature zalsa)
+		$(usex jack-netsource \
+			$(meson_feature opus opus_support) \
+			-Dopus_support=disabled)
+	)
+
+	meson_src_configure
+}

media-sound/jack-tools/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <name>Nedko Arnaudov</name>
+    <irc><nick>nedko</nick><network>libera.chat</network></irc>
+  </maintainer>
+  <maintainer type="project">
+    <name>LADI project, #ladi on libera.chat</name>
+    <irc><channel>#ladi</channel><network>libera.chat</network></irc>
+  </maintainer>
+</pkgmetadata>

media-sound/jack2/jack2-2.9999.ebuild

@@ -49,7 +49,7 @@ src_configure() {
 	filter-lto
 
 	local wafargs=(
-		--mandir="${EPREFIX}"/usr/share/man/man1 # override eclass' for man1
+#		--mandir="${EPREFIX}"/usr/share/man/man1 # override eclass' for man1
 
 		--alsa=$(usex alsa)
 		--celt=no
@@ -60,7 +60,6 @@ src_configure() {
 		--opus=$(usex opus)
 		--portaudio=no
 		--samplerate=$(usex libsamplerate)
-		--systemd=no
 		--winmme=no
 	)