media-sound/jack2: add a 2.23.1.ebuild (from tarball)

media-sound/jack2/Manifest

@@ -0,0 +1 @@
+DIST ladi-jack-2.23.1.tar.bz2 6750466 BLAKE2B be59a4a2cc3ce2863c3433502d1d32386367979b83e222915f9a1ea7a374ae4c7d80600864f6e65f8005449ab2d4f944106de6daf78b0fd2b1eca8c77e75f36f SHA512 4c90a641638b35256654fea7b688a3161c01d62e279b3da21d8e85447e91170d1c698c5aa9f74b744ee8eca3dcf67271499f9f2f50f56bb45e0409d3f4456f71

media-sound/jack2/jack2-2.23.1.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="threads(+)"
+inherit flag-o-matic python-single-r1 waf-utils
+
+#inherit git-r3
+#EGIT_REPO_URI="https://gitea.ladish.org/LADI/jack2.git"
+#EGIT_BRANCH="stable"
+#EGIT_COMMIT="7b534b955c024d03249e668323a3e5caefb00b33"
+
+SRC_URI="https://dl.ladish.org/jack2/ladi-jack-${PV}.tar.bz2"
+S=${WORKDIR}/ladi-jack-${PV}
+
+KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv x86"
+
+DESCRIPTION="LADI JACK2 is version of the jackdmp, a C++ version of the JACK low-latency audio server for multi-processor machines."
+HOMEPAGE="https://github.com/LADI/jack2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="2"
+IUSE="+alsa doc ieee1394 libsamplerate metadata opus pam"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	alsa? ( media-libs/alsa-lib )
+	sys-apps/dbus
+	libsamplerate? ( media-libs/libsamplerate )
+	ieee1394? ( media-libs/libffado )
+	metadata? ( sys-libs/db )
+	opus? ( media-libs/opus[custom-modes] )"
+RDEPEND="
+	${DEPEND}
+	pam? ( sys-auth/realtime-base )
+	!media-sound/jack-audio-connection-kit
+	!media-video/pipewire[jack-sdk(-)]"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+PDEPEND=""
+
+DOCS=( AUTHORS.rst NEWS.rst README.rst README_NETJACK2 )
+
+src_configure() {
+	# clients crash if built with lto
+	# https://github.com/jackaudio/jack2/issues/485
+	filter-lto
+
+	local wafargs=(
+		--alsa=$(usex alsa)
+		--celt=no
+		--db=$(usex metadata)
+		--doxygen=$(usex doc)
+		--firewire=$(usex ieee1394)
+		--iio=no
+		--opus=$(usex opus)
+		--portaudio=no
+		--samplerate=$(usex libsamplerate)
+		--winmme=no
+	)
+
+	waf-utils_src_configure "${wafargs[@]}"
+}
+
+src_compile() {
+	waf-utils_src_compile
+}
+
+src_install() {
+	waf-utils_src_install
+}