dev-libs/intel-compute-runtime: add 24.13.29138.7

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

dev-libs/intel-compute-runtime/Manifest

@@ -1 +1,2 @@
 DIST intel-compute-runtime-24.05.28454.17.tar.gz 6963009 BLAKE2B ca4840dedbea06bba7933ba74658eee602a6de19d35ec4baac1d41d5eb3041f16a4e7e82072f98961d19d2e7f97b9f3ad698ff84532f009537d23d7970162fc5 SHA512 f70967c649e7a17eab7fa550a2b344333357717021c16e3116eb47be45ea806bb0fc64795dad21027e7f055318f1e05c9e726c3e735dc3b7336de1839f6eae8e
+DIST intel-compute-runtime-24.13.29138.7.tar.gz 7056376 BLAKE2B e09c0a8e4b3f31b53879430401074f9861dc9384524dfe6c2bd87c9f12cd064688b08da1eefc7f9453141b008181bb66f187e4bf8f1fe0db8df4946b3cca6313 SHA512 01b3ded0d42c439314f83e9eac45dcdaaa401128fa83836d2cee4514351b8b43ae0b19a6485a16f5f08ef0d76595e6ee749fe1fff9a5ee04677e3d5ef33408da

dev-libs/intel-compute-runtime/intel-compute-runtime-24.13.29138.7.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+l0 +vaapi"
+
+RDEPEND="
+	>=dev-util/intel-graphics-compiler-1.0.15985.15
+	>=media-libs/gmmlib-22.3.17:=
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-libs/intel-metrics-discovery:=
+	dev-libs/intel-metrics-library:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-system-controller-0.8.16:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.16.1:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-22.24.23453-remove-fortify-sources.patch"
+)
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# See https://github.com/intel/compute-runtime/issues/531
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}